Calculation of Amplitudes Using Helicity Eigenstates Without Mass
Set of Programs to explain how to use traces to obtain helicity amplitudes
Author: Jorge C. Romão
Email: jorge.romao@tecnico.ulisboa.pt
Last Update: 10/12/2024

1- Definitions

We use the general expressions given in Eq. (6.11) of Thomson or Eq. (4.134) e (4.136) of the notes for Particle Physics

We should keep in mind that with the usual kinematics for the CM the angles for the 4 particles are

p1: θ  = 0, ϕ = 0
p2: θ  = π, ϕ = π
p3: θ , ϕ = 0
p4: θ → π - θ, ϕ = π 

Also E = (Sqrt[s])/2

Definition of the helicity spinors

uSpinorp1=Function[h,If[h>0,Sqrt[Sqrt[s]/2]{1,0,1,0},Sqrt[Sqrt[s]/2]{0,1,0,-1}]];

vSpinorp1=Function[h,If[h>0,Sqrt[Sqrt[s]/2]{0,-1,0,1},Sqrt[Sqrt[s]/2]{1,0,1,0}]];

uSpinorp2=Function[h,If[h>0,Sqrt[Sqrt[s]/2]{0,-1,0,-1},Sqrt[Sqrt[s]/2]{-1,0,1,0}]];

vSpinorp2=Function[h,If[h>0,Sqrt[Sqrt[s]/2]{1,0,-1,0},Sqrt[Sqrt[s]/2]{0,-1,0,-1}]];

uSpinorp3=Function[h,If[h>0,Sqrt[Sqrt[s]/2]{Cos[θ/2],Sin[θ/2],Cos[θ/2],Sin[θ/2]},Sqrt[Sqrt[s]/2]{-Sin[θ/2],Cos[θ/2],Sin[θ/2],-Cos[θ/2]}]];

vSpinorp3=Function[h,If[h>0,Sqrt[Sqrt[s]/2]{Sin[θ/2],-Cos[θ/2],-Sin[θ/2],Cos[θ/2]},Sqrt[Sqrt[s]/2]{Cos[θ/2],Sin[θ/2],Cos[θ/2],Sin[θ/2]}]];

uSpinorp4=Function[h,If[h>0,Sqrt[Sqrt[s]/2]{Sin[θ/2],-Cos[θ/2],Sin[θ/2],-Cos[θ/2]},Sqrt[Sqrt[s]/2]{-Cos[θ/2],-Sin[θ/2],Cos[θ/2],Sin[θ/2]}]];

vSpinorp4=Function[h,If[h>0,Sqrt[Sqrt[s]/2]{Cos[θ/2],Sin[θ/2],-Cos[θ/2],-Sin[θ/2]},Sqrt[Sqrt[s]/2]{Sin[θ/2],-Cos[θ/2],Sin[θ/2],-Cos[θ/2]}]];

Definition of Dirac Gamma Matrices

G0={{1,0,0,0},{0,1,0,0},{0,0,-1,0},{0,0,0,-1}};

G1={{0,0,0,1},{0,0,1,0},{0,-1,0,0},{-1,0,0,0}};

G2={{0,0,0,-I},{0,0,I,0},{0,I,0,0},{-I,0,0,0}};

G3={{0,0,1,0},{0,0,0,-1},{-1,0,0,0},{0,1,0,0}};

GammaVec={G0,G1,G2,G3};

Definition of scalar product in Minkowski space

dot=Function[{v1,v2},v1[[1]]v2[[1]]-Sum[v1[[i]]v2[[i]],{i,2,4}]];

t-channel vector currents

We have four different types of currents with four different helicity combinations each. However only eight will be non-zero.

Ju1u3

Ju1u3=Function[{h1,h3},Table[uSpinorp3[h3].G0. GammaVec[[i]].uSpinorp1[h1],{i,1,4}]];

Ju1u3[1,1]

Ju1u3[-1,-1]

Ju1u3[1,-1]

Ju1u3[-1,1]

Jv1v3

Jv1v3=Function[{h1,h3},Table[vSpinorp1[h1].G0. GammaVec[[i]].vSpinorp3[h3],{i,1,4}]];

Jv1v3[1,1]

Jv1v3[-1,-1]

Jv1v3[1,-1]

Jv1v3[-1,1]

Ju2u4

Ju2u4=Function[{h2,h4},Table[uSpinorp4[h4].G0. GammaVec[[i]].uSpinorp2[h2],{i,1,4}]];

Ju2u4[1,1]

Ju2u4[-1,-1]

Ju2u4[1,-1]

Ju2u4[-1,1]

Jv2v4

Jv2v4=Function[{h2,h4},Table[vSpinorp2[h2].G0. GammaVec[[i]].vSpinorp4[h4],{i,1,4}]];

Jv2v4[1,1]

Jv2v4[-1,-1]

Jv2v4[1,-1]

Jv2v4[-1,1]

s-channel vector currents

We have two different types of currents with four different helicity combinations each, one for the initial sate and another for the final state. However we just consider one of those because we take 1 and 3 as the particles and 2 and 4 as the anti-particles. However only four helicity combinations will be non-zero.

Ju1v2

Ju1v2=Function[{h1,h2},Table[vSpinorp2[h2].G0. GammaVec[[i]].uSpinorp1[h1],{i,1,4}]];

Ju1v2[1,1]

Ju1v2[-1,-1]

Ju1v2[1,-1]

Ju1v2[-1,1]

Ju3v4

Ju3v4=Function[{h3,h4},(Table[uSpinorp3[h3].G0. GammaVec[[i]].vSpinorp4[h4],{i,1,4}])//Simplify];

Ju3v4[1,1]

Ju3v4[-1,-1]

Ju3v4[1,-1]

Ju3v4[-1,1]

u-channel vector currents

We have four different types of currents with four different helicity combinations each. However only eight will be non-zero.

Ju1u4

Ju1u4=Function[{h1,h4},Table[uSpinorp4[h4].G0. GammaVec[[i]].uSpinorp1[h1],{i,1,4}]];

Ju1u4[1,1]

Ju1u4[-1,-1]

Ju1u4[1,-1]

Ju1u4[-1,1]

Ju2u3

Ju2u3=Function[{h2,h3},Table[uSpinorp3[h3].G0. GammaVec[[i]].uSpinorp2[h2],{i,1,4}]];

Ju2u3[1,1]

Ju2u3[-1,-1]

Ju2u3[1,-1]

Ju2u3[-1,1]

Jv1v4

Jv1v4=Function[{h1,h4},Table[vSpinorp1[h1].G0. GammaVec[[i]].vSpinorp4[h4],{i,1,4}]];

Jv1v4[1,1]

Jv1v4[-1,-1]

Jv1v4[1,-1]

Jv1v4[-1,1]

Jv2v3

Jv2v3=Function[{h2,h3},Table[vSpinorp2[h2].G0. GammaVec[[i]].vSpinorp3[h3],{i,1,4}]];

Jv2v3[1,1]

Jv2v3[-1,-1]

Jv2v3[1,-1]

Jv2v3[-1,1]

s-channel scalar currents

Ju3v4

Ju3v4Scalar=Function[{h1,h2},vSpinorp4[h2].G0.uSpinorp3[h1]];

Ju3v4Scalar[1,1]//Simplify

Ju3v4Scalar[1,-1]

Ju3v4Scalar[-1,1]

Ju3v4Scalar[-1,-1]//Simplify

2. Calculations of various processes in the CM frame

(e^(- )) (e^(+ ))→ (μ^(- )) (μ^(+ ))

The amplitude is given by                       M[h1,h2,h3,h4] = - e^2/s Ju1v2 . Ju3v4

M=Function[{h1,h2,h3,h4}, -e^2/s dot[Ju1v2[h1,h2],Ju3v4[h3,h4]]];

M[1,-1,1,-1]//Simplify

M[-1,1,-1,1]//Simplify

M[1,-1,-1,1]//Simplify

M[-1,+1,1,-1]//Simplify

MsqAverage=1/4 Sum[M[h1,h2,h3,h4]^2,{h1,-1,1,2},{h2,-1,1,2},{h3,-1,1,2},{h4,-1,1,2}]//Simplify

(e^(- )) (e^(+ ))→ (e^(- )) (e^(+ )) (Bhabha scattering)

The amplitude is (do not forget the minus sign between diagrams)

M[h1,h2,h3,h4] = - e^2/s Ju1v2 . Ju3v4 + e^2/t Ju1u3 . Jv2v4

M=Function[{h1,h2,h3,h4}, (-e^2/s dot[Ju1v2[h1,h2],Ju3v4[h3,h4]]+ e^2/t dot[Ju1u3[h1,h3],Jv2v4[h2,h4]])//Simplify];

M[-1,1,-1,1]

MAveragedBhabha=1/4(M[1,-1,1,-1]^2+M[-1,1,-1,1]^2+M[1,1,1,1]^2+M[-1,-1,-1,-1]^2+M[1,-1,-1,1]^2+M[-1,1,1,-1]^2)

Verification:

1/4Sum[M[h1,h2,h3,h4]^2,{h1,-1,1,2},{h2,-1,1,2},{h3,-1,1,2},{h4,-1,1,2}]

Verification: Comparing with Eq. 5.70 of my book ITC (version of 2021)

MAveragedBhabha2=MAveragedBhabha/.{Cos[θ ]-> 1+2 t/s,Cos[θ/2]^4-> 1+t^2/s^2+2t/s}

Simplify[MAveragedBhabha2- 2 e^4((t^2+(s+t)^2)/s^2 + (s^2+(s+t)^2)/t^2+2(s+t)^2/s/t)]

(e^(- )) (e^(- ))→ (e^(- )) (e^(- )) (Möller scattering)

The amplitude is (do not forget the minus sign between diagrams)

M[h1,h2,h3,h4] = - e^2/t Ju1u3 . Ju2u4 + e^2/u Ju1u4 . Ju2u3

M=Function[{h1,h2,h3,h4}, (-e^2/t dot[Ju1u3[h1,h3],Ju2u4[h2,h4]]+ e^2/u dot[Ju1u4[h1,h4],Ju2u3[h2,h3]])//Simplify];

MAveragedMoller=1/4(M[1,1,1,1]^2+M[1,-1,1,-1]^2+M[-1,1,-1,1]^2+M[-1,-1,-1,-1]^2+M[1,-1,-1,1]^2+M[-1,1,1,-1]^2)

Verification:

1/4Sum[M[h1,h2,h3,h4]^2,{h1,-1,1,2},{h2,-1,1,2},{h3,-1,1,2},{h4,-1,1,2}]

MAveragedMoller2=MAveragedMoller /. t+u-> s

MAveragedMoller3=MAveragedMoller2/. {u-> -s Cos[θ/2]^2,t-> -s Sin[θ/2]^2}

Verification: Comparing with Eq. 5.215 of my book ITC (version of 2021)

Simplify[MAveragedMoller3-2 e^4((1+Cos[θ/2]^4)/Sin[θ/2]^4+ 2/(Cos[θ/2]^2 Sin[θ/2]^2)+ (1+ Sin[θ/2]^4)/Cos[θ/2]^4)]

TimeUsed[]