Program for Bhabha Using FeynCalc FermionSpinSum function
Works with FeynCalc 10.1.0
Last update: 09/12/2024
Author: Jorge C. Romão
email: jorge.romao@tecnico.ulisboa.pt

<<FeynCalc`

The Amplitudes

M1= e^2/t  SpinorUBar[p3,0].GA[mu].SpinorU[p1,0] SpinorVBar[p2,0].GA[mu].SpinorV[p4,0]

M2= - e^2/s SpinorVBar[p2,0].GA[mu].SpinorU[p1,0] SpinorUBar[p3,0].GA[mu].SpinorV[p4,0]

The Total Amplitude

MTotal = M1 + M2

The Complex Conjugate of the Total Amplitude

MTotalC= ComplexConjugate[MTotal] /. mu-> muC

MsqAvg1= 1/4  FermionSpinSum[MTotal MTotalC]/. DiracTrace-> TR//Contract //Simplify

Substitute the Kinematics (do not forget to use FeynCalc External)

MsqAvg1//InputForm

MsqAvg2= MsqAvg1//FCE

MsqAvg2//InputForm

onshell={SP[p1,p2]->s/2,SP[p3,p4]->s/2,SP[p1,p3]->-t/2,SP[p2,p4]->-t/2,SP[p1,p4]->-u/2,SP[p2,p3]->-u/2};

MsqAvg3=MsqAvg2 /. onshell//Simplify

MsqAvg = MsqAvg3 /. u-> (-s-t)//Simplify

This is in agreement with the previous calculation, see Eq. 5.85 of my Book QFT with João Silva

Eq570=2 e^4((t^2+(s+t)^2)/s^2+(s^2+(s+t)^2)/t^2+2(s+t)^2/s/t)//Simplify

TimeUsed[]